Face Detect Library / 얼굴 인식 라이브러리

프로세싱용 얼굴 인식 라이브러리(인텔 맥)
openCV를 이용

facedetect library

June 8, 2008 8:30 AM | Permalink | Comments (0)

트랜지션

Download file

November 20, 2007 10:11 AM | Permalink | Comments (0)

sound파일 재생

Download file

November 19, 2007 5:00 PM | Permalink | Comments (0)

typography : 폰트 사용 / 텍스트 표시

0. PFont() : 폰트 선언
PFont는 프로세싱에서 사용하는 폰트 클래스입니다. 폰트를 사용하기 위해서는 반드시 폰트 클래스를 선언해야 합니다.

PFont name

1. loadFont() : vlw 폰트 사용
화면에 텍스트를 표시하기 위해서는 loadFont()함수로 우선 폰트를 로드해야 합니다.
프로세싱에서 기본적으로 사용할 수 있는 폰트는 vlw라는 확장자를 가진 폰트입니다.
이 폰트는 프로세싱에서 밖에 사용할 수 없는 비트맵 폰트로 프로세싱을 인스톨해도 설치되지 않기 때문에 사용자가 직접 만들어야 합니다. Tools > Create Font 메뉴를 선택하면 시스템에 설치된 폰트리스트(위 그림)가 나옵니다. 리스트에서 사용할 폰트와 사이즈를 정하고 OK를 누르면 data폴더에 .vlw 폰트가 생성됩니다.

loadFont("fontname.vlw")

2. createFont() : ttf, otf 폰트 사용
createFont()함수를 이용해서 vlw폰트이외에 시스템이나 data폴더에 설치된 ttf, otf폰트를 사용할 수 있습니다.

createFont("fontname", size)
createFont("fontname", size, smooth)

3. textFont() : 폰트 선택, 사이즈 지정
textFont(font, size)
font : 사용할 폰트를 지정
size : 폰트 사이즈 지정

4. text() : 텍스트 표시
text(data, x, y)
data : 표시할 텍스트
x, y : 텍스트를 표시할 좌표지정

5. fill() : 텍스트 색 지정

October 17, 2007 7:36 PM | Permalink | Comments (0)

mosaic

import JMyron.*;

JMyron m;//a camera object

void setup(){
size(320,240);
m = new JMyron();//make a new instance of the object
m.start(40,30);//start a capture at 320x240
m.findGlobs(0);//disable the intelligence to speed up frame rate
println("Myron " + m.version());
noStroke();
}

void draw(){
m.update();//update the camera view
int[] img = m.image(); //get the normal image of the camera
int i = 0;
for(int y = 0; y< 30;y++) {
for(int x = 0; x< 40; x++) {
fill(color(img[i]));
rect(x*8,y*8,8,8);
i++;
}
}
}

void mousePressed(){
m.settings();//click the window to get the settings
}

public void stop(){
m.stop();//stop the object
super.stop();
}

August 30, 2007 2:53 PM | Permalink | Comments (0)

color->grey scale/그레이 스케일 변환

import JMyron.*;

JMyron m;//a camera object

void setup(){
size(320,240);
m = new JMyron();//make a new instance of the object
m.start(width,height);//start a capture at 320x240

m.findGlobs(0);//disable the intelligence to speed up frame rate
println("Myron " + m.version());
}

void draw(){
m.update();//update the camera view
int[] img = m.image(); //get the normal image of the camera
loadPixels();
for (int i = 0;i < img.length;i++) {
int grey = (int)brightness(img[i]);
pixels[i] = color(grey,grey,grey);
// int grey = ((img[i] >> 16 & 0xff) + (img[i] >> 8 & 0xff) + (img[i] & 0xff))/3;
// pixels[i] = (int)(0xff000000 | grey << 16 | grey << 8 | grey);
}
updatePixels();
}

void mousePressed(){
m.settings();//click the window to get the settings
}

public void stop(){
m.stop();//stop the object
super.stop();
}

August 30, 2007 2:52 PM | Permalink | Comments (0)

color->b&w/이진 변환

import JMyron.*;

JMyron m;//a camera object
int threshold;

void setup(){
size(320,240);
m = new JMyron();//make a new instance of the object
m.start(width,height);//start a capture at 320x240

m.findGlobs(0);//disable the intelligence to speed up frame rate
println("Myron " + m.version());
threshold = 100;
}

void draw(){
m.update();//update the camera view
int[] img = m.image(); //get the normal image of the camera

for (int i = 0;i < img.length;i++) {
if (brightness(img[i]) > threshold) img[i] = 0xffffffff;
else img[i] = 0xff000000;
}

loadPixels();
arraycopy(img,pixels); //draw each pixel to the screen
updatePixels();
}

void mousePressed(){
m.settings();//click the window to get the settings
}

public void stop(){
m.stop();//stop the object
super.stop();
}

August 30, 2007 2:50 PM | Permalink | Comments (0)

frame differencing/움직임 감지

현재 프레임과 바로 앞 프레임의 차이를 보여주는 예제입니다.

/**
* Frame Differencing
* by Golan Levin.
*/

import JMyron.*;

int numPixels;
int[] previousFrame;
JMyron m;

void setup() {
size(320,240); // Change size to 320 x 240 if too slow at 640 x 480
m = new JMyron();
m.start(width, height);
numPixels = width * height;
previousFrame = new int[numPixels];
m.findGlobs(0);
}

void draw() {
m.update();//update the camera view
int[] img = m.image(); //get the normal image of the camera

loadPixels();
int movementSum = 0; // Amount of movement in the frame
for (int i = 0; i < numPixels; i++) { // For each pixel in the video frame...
color currColor = img[i];
color prevColor = previousFrame[i];
// Extract the red, green, and blue components from current pixel
int currR = (int)red(currColor);//(currColor >> 16) & 0xFF; // Like red(), but faster
int currG = (int)green(currColor);//(currColor >> 8) & 0xFF;
int currB = (int)blue(currColor);//currColor & 0xFF;
// Extract red, green, and blue components from previous pixel
int prevR = (int)red(prevColor);//(prevColor >> 16) & 0xFF;
int prevG = (int)green(prevColor);//(prevColor >> 8) & 0xFF;
int prevB = (int)blue(prevColor);//prevColor & 0xFF;
// Compute the difference of the red, green, and blue values
int diffR = abs(currR - prevR);
int diffG = abs(currG - prevG);
int diffB = abs(currB - prevB);
// Add these differences to the running tally
movementSum += diffR + diffG + diffB;
// Render the difference image to the screen
pixels[i] = color(diffR, diffG, diffB);
previousFrame[i] = currColor;
}
// To prevent flicker from frames that are all black (no movement),
// only update the screen if the image has changed.
if (movementSum > 0) {
updatePixels();
println(movementSum); // Print the total amount of movement to the console
}
}

August 30, 2007 2:47 PM | Permalink | Comments (0)

color tracking

import JMyron.*;

JMyron m;//a camera object
color trackColor;

void setup()
{
size(320, 240);

m = new JMyron();//make a new instance of the object
m.start(width,height);//start a capture at 320x240

m.findGlobs(0);//disable the intelligence to speed up frame rate
println("Myron " + m.version());

trackColor = color(255); // Start off tracking for white
noFill();
strokeWeight(4.0);
stroke(0);
}

void draw()
{
m.update();//update the camera view
int[] img = m.image(); //get the normal image of the camera

loadPixels();
arraycopy(img,pixels);
updatePixels();

float closestDiff = 500.0f;
int closestX = 0;
int closestY = 0;

for ( int x = 0; x < width; x++) {
for ( int y = 0; y < height; y++) {
int loc = x + y*width;
color currentColor = img[loc];
float r1 = red(currentColor);
float g1 = green(currentColor);
float b1 = blue(currentColor);
float r2 = red(trackColor);
float g2 = green(trackColor);
float b2 = blue(trackColor);

float d = dist(r1,g1,b1,r2,g2,b2);

if (d < closestDiff) {
closestDiff = d;
closestX = x;
closestY = y;
}
}
}
ellipse(closestX,closestY,16,16);
}

void mousePressed() {
int loc = mouseX + mouseY*width;
trackColor = pixels[loc];
}

August 21, 2007 10:04 PM | Permalink | Comments (0)

비디오 입력 / video - jmyron

/*

a very simple example that draws the camera pixels
to the screen using the pixel[] array.

last tested to work in Processing 0090

JTNIMOY

*/

import JMyron.*;

JMyron m;//a camera object

void setup(){
size(320,240);
m = new JMyron();//make a new instance of the object
m.start(width,height);//start a capture at 320x240

m.findGlobs(0);//disable the intelligence to speed up frame rate
println("Myron " + m.version());
}

void draw(){
m.update();//update the camera view
int[] img = m.image(); //get the normal image of the camera

loadPixels();
arraycopy(img,pixels); //draw each pixel to the screen
updatePixels();
}

void mousePressed(){
m.settings();//click the window to get the settings
}

public void stop(){
m.stop();//stop the object
super.stop();
}

August 21, 2007 6:27 PM | Permalink | Comments (0)